Nand2Tetrisもくもく昨日の続き。予想はしていたけど、シルバーウィーク中の読了は無理っぽいね。。
コンピュータシステムの理論と実装 ―モダンなコンピュータの作り方
2章 ブール算術
加算回路を作成して、もっと汎用的に様々な計算が可能なALU(Arithmetic Logic Unit)を作成します。
もうそろそろ絵を書くのは無理な感じ。
nand2tetris-memo/02 at master ・ hirak/nand2tetris-memo
ALU
最初にALUが出てきた時は、入力がx[16]とy[16]、制御ビットが6つの出力がout[16]およびzr, ngとすごく入出力が多かったので、いきなりこれ実装するのは無理なんじゃ。。という気になってました。
教科書には、素直に文章に書いてあるとおり実装すれば行けるよーとのことだったので、こんな感じになりました。
// This file is part of www.nand2tetris.org
// and the book "The Elements of Computing Systems"
// by Nisan and Schocken, MIT Press.
// File name: projects/02/ALU.hdl
/**
* The ALU (Arithmetic Logic Unit).
* Computes one of the following functions:
* x+y, x-y, y-x, 0, 1, -1, x, y, -x, -y, !x, !y,
* x+1, y+1, x-1, y-1, x&y, x|y on two 16-bit inputs,
* according to 6 input bits denoted zx,nx,zy,ny,f,no.
* In addition, the ALU computes two 1-bit outputs:
* if the ALU output == 0, zr is set to 1; otherwise zr is set to 0;
* if the ALU output < 0, ng is set to 1; otherwise ng is set to 0.
*/
// Implementation: the ALU logic manipulates the x and y inputs
// and operates on the resulting values, as follows:
// if (zx == 1) set x = 0 // 16-bit constant
// if (nx == 1) set x = !x // bitwise not
// if (zy == 1) set y = 0 // 16-bit constant
// if (ny == 1) set y = !y // bitwise not
// if (f == 1) set out = x + y // integer 2's complement addition
// if (f == 0) set out = x & y // bitwise and
// if (no == 1) set out = !out // bitwise not
// if (out == 0) set zr = 1
// if (out < 0) set ng = 1
CHIP ALU {
IN
x[16], y[16], // 16-bit inputs
zx, // zero the x input?
nx, // negate the x input?
zy, // zero the y input?
ny, // negate the y input?
f, // compute out = x + y (if 1) or x & y (if 0)
no; // negate the out output?
OUT
out[16], // 16-bit output
zr, // 1 if (out == 0), 0 otherwise
ng; // 1 if (out < 0), 0 otherwise
PARTS:
// if (zx == 1) set x = 0 // 16-bit constant
Mux16(a=x, b[0..15]=false, sel=zx, out=xx);
// if (nx == 1) set x = !x // bitwise not
Not16(in=xx, out=notx);
Mux16(a=xx, b=notx, sel=nx, out=xxx);
// if (zy == 1) set y = 0 // 16-bit constant
Mux16(a=y, b[0..15]=false, sel=zy, out=yy);
// if (ny == 1) set y = !y // bitwise not
Not16(in=yy, out=noty);
Mux16(a=yy, b=noty, sel=ny, out=yyy);
// if (f == 1) set out = x + y // integer 2's complement addition
// if (f == 0) set out = x & y // bitwise and
Add16(a=xxx, b=yyy, out=xplusy);
And16(a=xxx, b=yyy, out=xandy);
Mux16(a=xandy, b=xplusy, sel=f, out=fout);
// if (no == 1) set out = !out // bitwise not
// if (out < 0) set ng = 1
Not16(in=fout, out=notfout);
Mux16(a=fout, b=notfout, sel=no, out=out, out[0..7]=aout, out[8..15]=bout, out[15]=ng);
// if (out == 0) set zr = 1
Or8Way(in=aout, out=zr1);
Or8Way(in=bout, out=zr2);
Or(a=zr1, b=zr2, out=any);
Not(in=any, out=zr);
}
予めパターンを２つとも用意しておいて、マルチプレクサで分岐して結果を選択する、みたいな書き方で最後まで書けました。
HDLのメモ
いまいち言語仕様がわからず苦労したところをメモ。
出力先は複数書ける
And16(a=x, b=y, out[0..7]=aout, out[8..15]=bout, out=out, out=myout);
出力先が1ビットならばあまり便利な場面が無いですが、複数ビットを出力する場合は部分的に別々に出力したり、別名をつけたりできます。
内部バスはスライス表記ができない
複数ビットを代入するような書き方をすると、勝手に複数ビットに対応したピン（＝内部バス）ができます。この内部バスは、スライス表記ができないようです。
// inputとして定義したバスはスライス表記ができる
CHIP Or16Way {
IN
in[16];
OUT
out;
PARTS:
Or8Way(in=in[0..7], out=aout);
Or8Way(in=in[8..15], out=bout);
Or(a=aout, b=bout, out=out);
}
// ところが自分で定義した暗黙の内部バスはスライスできない
CHIP NotOr16Way {
IN
in[16];
OUT
out;
PARTS:
Not16(in=in, out=notin);
Or8Way(in=notin[0..7], out=aout); //←エラー！
Or8Way(in=notin[8..15], out=bout);
Or(a=aout, b=bout, out=out);
}
対策としてはこんなふうに出力時に分岐すればよいようです。
// 出力時に別名をつければOK
CHIP NotOr16Way {
IN
in[16];
OUT
out;
PARTS:
Not16(in=in, out[0..7]=notin1, out[8..15]=notin2);
Or8Way(in=notin1, out=aout);
Or8Way(in=notin2, out=bout);
Or(a=aout, b=bout, out=out);
}
これでHDLもある程度慣れてきたかな。